Behaviour for a repository of prompts served by a GenMCP.Suite.

Prompts are reusable message templates a client can fetch and replay to an LLM. A prompt repository groups related prompts under a common name prefix, answers prompts/list to advertise them, and answers prompts/get to build a concrete prompt from the arguments the client supplies.

The prefix is what ties the two requests together. The Suite routes a prompts/get to the repository whose prefix the requested name starts with, so every name a repository lists must begin with its prefix, and the prefixes of the configured repositories must not collide.

A repository is a thin adapter: keep the prompt text and argument shapes in a plain module of your own, and let the callbacks route to it. The three required callbacks answer one question each, which prefix the prompts live under (prefix/1), which prompts exist (list/3), and how to build one (get/4).

Minimal implementation

A repository that serves a single greeting prompt under the support/ prefix. list/3 advertises it, and get/4 fills in the customer name the client passed, building the result with the GenMCP.MCP.V2607 helpers:

defmodule MyApp.SupportPrompts do
  @behaviour GenMCP.Suite.PromptRepo

  alias GenMCP.MCP.V2607, as: MCP

  @impl true
  def prefix(_arg), do: "support/"

  @impl true
  def list(_cursor, _channel, _arg) do
    prompts = [
      %{
        name: "support/greeting",
        description: "Greet a customer by name",
        arguments: [%{name: "name", description: "Customer name", required: true}]
      }
    ]

    {prompts, nil}
  end

  @impl true
  def get("support/greeting", %{"name" => name}, _channel, _arg) do
    result =
      MCP.get_prompt_result(
        description: "Greet a customer by name",
        text: "Greet #{name} warmly and ask how you can help."
      )

    {:ok, result}
  end

  def get(_name, _arguments, _channel, _arg), do: {:error, :not_found}
end

Wiring a repository into the server

A repository is given to the Suite through its :prompts option. Because the Suite is the default :server, those options are passed straight to the transport plug in your router. Each entry is a bare module or a {module, arg} tuple, where arg is handed back to every callback as the trailing argument:

# In your router
forward "/mcp", GenMCP.Transport.StreamableHTTP,
  server_name: "My App",
  server_version: "1.0.0",
  prompts: [MyApp.SupportPrompts]

Provider arguments

The arguments the callbacks receive follow the conventions shared by all Suite providers, documented in GenMCP.Suite:

• channel is the request-scoped GenMCP.Mux.Channel.t/0, carrying read-only client meta and auth assigns. list/3 and get/4 receive it as the second-to-last argument, so a repository can tailor what it exposes to the caller.
• arg is the value configured alongside the module as {module, arg} (a bare module is treated as {module, []}). It is the trailing argument of every callback, letting one generic repository module be configured differently in different Suites.